GUICtrlCreateUpdown
Beschreibung anzeigen in
Erstellt ein Pfeiltasten-Control für die GUI.
GUICtrlCreateUpdown ( inputcontrolID [, style = -1] )
Parameter
| inputcontrolID | Die Control-ID des Input-Controls, zu dem die beiden Pfeiltasten hinzugefügt werden sollen (zum bequemen Erhöhen/Erniedrigen von (Zahlen-)werten). Oder -1 für das zuletzt erzeugte Control. |
| style | [optional] Legt den Stil des Controls fest. Siehe Anhang GUI-Stile für Controls. Standard (-1) : $GUI_SS_DEFAULT_UPDOWN. Erzwungene Stile : $UDS_SETBUDDYINT und $UDS_ALIGNRIGHT wenn keine Ausrichtung definiert ist. |
Rückgabewert
| Erfolg: | Die Identifikationsnummer (Control-ID) des neuen Controls. |
| Fehler: | 0. |
Bemerkungen
Um die oben angegebenen Werte verwenden zu können, muss #include <UpDownConstants.au3> in das Skript eingefügt werden.
Die Maximal- und Minimalwerte können mit GUICtrlSetLimit() gesetzt werden.
Wird die obere Pfeiltaste gedrückt, so erhöht standardmäßig Windows den Wert.
Standardmäßig wird eine Höhenanpassung entsprechend des zugehörigen Input-Controls vorgenommen.
- - - - - - - - Erklärung der Controls - - - - - - - -
Verwandte Funktionen
GUICtrlCreateInput, GUICtrlSetData, GUICtrlSetLimit
Beispiel
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>
Example()
Func Example()
GUICreate("Meine GUI mit UpDown", -1, -1, -1, -1, $WS_SIZEBOX)
Local $idInput = GUICtrlCreateInput("2", 10, 10, 50, 20)
GUICtrlCreateUpdown($idInput)
; Versuch das Eingabe-Control in der Größe zu verändern
GUICtrlSetPos($idInput, 10, 10, 100, 40)
GUISetState(@SW_SHOW)
Local $idMsg
; Die Schleife wiederholt sich, bis der Benutzer die Beenden-Aktion der GUI auslöst.
While 1
$idMsg = GUIGetMsg()
Switch $idMsg
Case $GUI_EVENT_CLOSE
ExitLoop
EndSwitch
WEnd
MsgBox($MB_SYSTEMMODAL, "Updown", GUICtrlRead($idInput))
EndFunc ;==>Example